Planets

A 10-line TurboBASIC XL program for the Atari 8-bit computer
Written for 2014 NOMAM programming competition

Bill Kendrick, February 16, 2014

An entry for the NOMAM 2014 10-line TurboBASIC XL game competition.

Objective

When the game begins, two randomly-sized planets appear at random spots on the left and right halves of the screen. Each player uses a joystick to control a gun on the planet; push left and right to rotate around the surface. Pressing fire launches a missile (each player may have only one missile in flight at a time. Good old fashioned arbitary limits!)

When a missile strikes, a circular chunk of planet is removed. If a missile hits near the center of a planet, that planet explodes, the player on the other planet wins, and the game ends. (A new game starts automatically.) Yes, you can fire upon your own planet. You might do this accidentally while trying a slingshot maneuvor, or if your planet is quite large, and pulls your missile back towards you before hitting your opponent's!

Your gun cannot remain over a hole on the surface. In fact, if there's no ground on either side of your gun, either, you won't be able to move much at all!

Development

I wanted to create a game that used rotation, with the goal of pre-calculating sine and cosine for for enhanced speed. My older son had been playing a ton of "Angry Birds: Space" on our Roku, and decided to make a artillery game where the players are on the surface of planets, firing at each other. Both planets' gravity affect the missiles' trajectories.

This game was fairly hard to squeeze down to 10 lines; it hovered at 11 lines for quite a while, until I started having subroutines do work, and determined that "END." in TurboBASIC XL is short for "ENDIF", allowing me to squeeze in a few more precious characters on some lines. You'll notice line 30 is short, but there's nowhere else to put it; it's a one-time set-up routine!

Line-by-line Breakdown of the Source Code

Set-up

10 DEG :GRAPHICS 23:DIM X(2),Y(2),R(2),A(2),B(2),BX(2),BY(2),BXM(2),BYM(2),CS(36),SN(36):FOR I=0 TO 1:X(I)=ABS(160*I-30-RAND(20))

• Switch trigonometric functions to degrees (vs radians) mode
• Go into 160x96 graphics mode with no text window
• Create arrays for the planet location and size (X, Y, R), whether a missile is in flight (B), and the missile's position (BX, BY) and speed/trajectory (BXM, BYM), and the pre-calculated cosine and sine values (CS, SN)
• Begin a loop to position and draw the planets...
  • Set the planet's X-position

20 Y(I)=28+RAND(40):R(I)=15+RAND(10):COLOR I+1:CIRCLE X(I),Y(I),R(I):PAINT X(I),Y(I):B(I)=0:A(I)=I*18:NEXT I

• ...positioning and drawing the planets...
  • Set the planet's Y-position and radius
  • Draw and fill a circle for the planet
  • Disable the missle (B)
    (redundant; would be filled with '0' at start-up)
  • Position the player's gun; player 1 (on the left) faces right; player 2 (on the right) faces left

30 FOR I=0 TO 35:CS(I)=COS(I*10):SN(I)=SIN(I*10):NEXT I

• Fill in the pre-calculated trig. values

Main loop

100 TRAP 100:FOR I=0 TO 1:CR=0:GOSUB 1000:Q=OA:S=STICK(I)*STRIG(I):IF S=11:A(I)=(A(I)+1) MOD 36:ENDIF :IF S=7 THEN A(I)=(A(I)+35) MOD 36

• In case of any out-of-bounds plotting, go back here as a last resort
• For each player...
• Set color to 0 (background/erase) and jump to the routine that draws the player; it has the side-effect of setting the variables which we reuse later, within this, the main loop:
  • OA - current player's position around the planet (angle)
  • XM and YM - cosine and negative-sine of that angle, times 3
  • R - radius of the player's planet, plus 2
  • X and Y - on-screen position of the player's position around the planet
• Keep track of the player's old position (Q)
• Get either the player's joystick position, or 0, if they're pressing fire (S)
• If pushing left, rotate counter-clockwise; wrap back to 0 degrees if we go above 360
• If pushing right, rotate clockwise; wrap back to 360 degrees if we go under 0

105 CR=I+1:GOSUB 1000:LOCATE X-XM,Y-YM,C:IF C=0:A(I)=Q:ENDIF :IF S+B(I)=0 THEN B(I)=100:BX(I)=X:BY(I)=Y:BXM(I)=XM:BYM(I)=YM

• ...for each player...
  • Set color based on which player and jump to the routine that draws the player
  • Look "underneath" the player, towards the planet's surface (at X-XM,Y-YM; stored in C)
  • If it's the background color (surface has been destroyed), put the player's gun back to where it was before we moved it based on any joystick input
  • If the player is pressing fire (S=0), and their missile is not in flight (B(I)=0)...
    • Launch their missile (it will last up to 100 'ticks', aka iteratons of the main loop))
    • Position the missile at the gun's position
    • Set it's starting speed/trajectory to be '3' (since XM and YM were set to cosine/negative-size times three)

110 IF B(I):B(I)=B(I)-1:COLOR 0:PLOT BX(I),BY(I):BX(I)=BX(I)+BXM(I):BY(I)=BY(I)+BYM(I):BX=BX(I):BY=BY(I):LOCATE BX,BY,C:IF C

• ...for each player...
  • If our missile is in flight...
    • Tick the missile's timer down by one
    • Erase at the missile's current location
    • Move the missile in its speed/trajectory
    • Copy its new location into BX and BY
    • See what's at the missile's new location (store into C)
    • If it's not background...

120 B(I)=0:FOR J=0 TO 5:CIRCLE BX,BY,J:NEXT J:GOSUB 4000:ENDIF :IF B(I):COLOR I+1:PLOT BX,BY:GOSUB 3000:ENDIF :ENDIF :NEXT I:GOTO 100

• ...for each player...
  • ...missile is in flight...
    • ...new position does not background color...
      • Terminate this missile
      • In a loop from 0 to 5, draw a circle (in the background color, which we set in line 110)
      • Jump to the X subroutine
    • If missile is still in flight...
      • Draw the missile in our color
      • Jump to the subroutine the affects missiles' trajectories based on the planets
• Repeat the main loop

Subroutines

Draw the player's gun on the surface of the planet

1000 COLOR CR:OA=A(I):XM=CS(OA):YM=-SN(OA):R=R(I)+2:X=X(I)+XM*R:Y=Y(I)+YM*R:PLOT X,Y:XM=XM*3:YM=YM*3:RETURN

• Use the color requested (CR)
• Copy the gun's position around the planet (angle) into another variable (OA)
• Copy the cosine and negative-sine of the gun's angle (XM, YM)
• Copy the planet's radius, plus 2 (to draw the gun just above the surface) (R)
• Determine the screen position of the gun (X, Y)
• Draw the gun
• Multiply XM and YM by three, so they can be used for both looking below the gun to see if the surface is still intact, and to set the initial speed of a missile (both on line 105)

Affect a missile's speed and trajectory based on the positions and sizes of the planets

3000 FOR J=0 TO 1:BXM(I)=BXM(I)-(BX(I)-X(J))/(500-R(J)):BYM(I)=BYM(I)-(BY(I)-Y(J))/(500-R(J)):NEXT J:RETURN

• For each planet...
  • Change both the horizontal (BXM) and vertical (BYM) speed and direction (positive/negative) based on how far away the planet is, scaled by the planet's radius

Erase missile after collision, and check for hitting center of planet (and do game-over, if so)

4000 PLOT BX,BY:FOR J=0 TO 1:IF ABS(BX-X(J))+ABS(BY-Y(J))<=5:FOR Z=0 TO 255:POKE 708+J,255-Z:SOUND 0,Z,4,Z/16:NEXT Z:RUN :ENDIF :NEXT J:RETURN

• Draw a pixel at the missile's position (since CIRCLE can't draw a point, it seems)
• For each planet...
  • If we are near the center...
    • In a loop from 0 to 255 (Z)...
      • Change the color of the planet (when we hit 255, the planet will be black, like the background)
    • Restart the program

Download

• PLANETS.TBS - tokenized TurboBASIC XL file
• planets_20140216.atr - ATR disk ima ge containing:
  • MyDOS 4.53/3 (DOS.SYS, DUP.SYS)
  • TurboBASIC XL (auto-run, TBASIC.AR0)
  • The game (TBXL auto-run, AUTORUN.BAS; except for the filename , same as PLANETS.TBS stand-alone file, above)

Bill Kendrick, 2014, nbs@sonic.net, New Breed Software
Other games I wrote for NOMAM 2014